Search text in multiple sheets and display adjacent cell along with sheet info

Sub SearchAll()
    Dim strName As String
    Dim ws As Worksheet
    Dim fCell As Range
    Dim wsMain As Worksheet
    Dim firstAdd As String
    
    'Where does output go?
    Set wsMain = Worksheets("Query")
    
    'Get info from user?
    strName = InputBox("What name do you want to search for?", "Name")
    
    If strName = "" Then Exit Sub 'User cancelled
    
    Application.ScreenUpdating = False
    
    'Clear old data
    wsMain.Range("A2:B20000").ClearContents
    
    For Each ws In ThisWorkbook.Worksheets
        'Clear values
        Set fCell = Nothing
        firstAdd = ""
        
        If ws.Name <> wsMain.Name Then
            Set fCell = ws.Range("B:B").Find(what:=strName, LookIn:=xlValues, lookat:=xlPart, MatchCase:=False)
            
            If Not fCell Is Nothing Then
                'We found something!
                firstAdd = fCell.Address
                
                Do
                    With wsMain
                        .Cells(.Rows.Count, "A").End(xlUp).Offset(1).Value = fCell.Offset(0, 1).Value
                        .Cells(.Rows.Count, "B").End(xlUp).Offset(1).Value = ws.Name & "; " & _
                            fCell.Address(False, False) & "; " & fCell.Value
                    End With
                    
                    Set fCell = ws.Range("B:B").FindNext(fCell)
                Loop Until fCell.Address = firstAdd
            End If
        End If
    Next ws
    
    Application.ScreenUpdating = True
    
End Sub