Send emails

Option Explicit

Sub sendEmails()
    Dim emailSubject As String
    Dim emailBody As String
    Dim emailAddresses As Variant
    Dim i As Long
    
    With Sheets("Sheet1")
        With .Range("C1", .Cells(.Rows.Count, "C").End(xlUp))
            If Rows.Count > 1 Then
                emailAddresses = .Value
            ElseIf .Cells(1, 1).Value <> "" Then
                ReDim emailAddresses(1 To 1, 1 To 1)
                emailAddresses(1, 1) = .Cells(1, 1).Value
            End If
        End With
        If IsArray(emailAddresses) Then
            emailSubject = .Range("A1").Value
            emailBody = .Range("B1").Value
            
            'Two options for you here:
            
            'The fist, and easiest is the following:
            sendMail emailSubject, emailBody, emailAddresses ', True '<-Optional parameter to send as a blind copy
            
            'The second way would be to loop over the array.
            'Commented out because it's not as quick as option 1:
            'For i = LBound(emailAddresses) To UBound(emailAddresses)
            '   sendMail emailSubject, emailBody, emailAddresses(i, 1)
            'Next i

        End If
    End With
End Sub

Sub sendMail(ByVal mailSubject As String, _
        ByVal mailBody As String, ByVal recipients As Variant, _
        Optional ByVal blindCopy As Boolean = False)
        
    Dim OutApp As Object
    Dim OutMail As Object
    Dim i As Long
    Dim recipient As String
    
    If IsArray(recipients) Then
        i = -1
        On Error Resume Next
        i = UBound(recipients, 2)
        On Error GoTo 0
        If i = -1 Then
            For i = LBound(recipients) To UBound(recipients)
                recipient = recipient & IIf(recipient = "", "", ";") & recipients(i)
            Next i
        ElseIf i = LBound(recipients, 2) Then
            For i = LBound(recipients) To UBound(recipients)
                recipient = recipient & IIf(recipient = "", "", ";") & recipients(i, LBound(recipients))
            Next i
        End If
    ElseIf TypeName(recipients) = "String" Then
        recipient = recipients
    End If
    
    If LenB(recipient) Then
        Set OutApp = CreateObject("Outlook.Application")
        Set OutMail = OutApp.CreateItem(0)
        On Error Resume Next
        With OutMail
            If blindCopy Then
                .Bcc = recipient
            Else
                .To = recipient
            End If
            .Subject = mailSubject
            .Body = mailBody
            'You can add files also like this
            '.Attachments.Add ("C:\text.txt")
            .Send  'Or use .Display
        End With
        On Error GoTo 0
        Set OutMail = Nothing
    End If
End Sub