Typed number auto convert as date

mamun.ges · Sep 14th 2021

Hi,

I want to know about know something.

Suppose I have a workbook where lots of date to be input. The date format is like dd/mm/yyyy.

I have to type "/" every separation of day month and year.

Now the thing is, supposed I type 02092021 its automatically converts into 02/09/2021.

also, select which column converts automatically as date, otherwise, all number converts as a date make my workbook invalid .

Is it possible to convert a string as a date?

any suggestion

Thanks in advance.

**royUK** · Sep 15th 2021

It's possible to do that with VBA.

Chip Pearson wrote some code to do this.

Quick Input Dates

mamun.ges · Sep 15th 2021

Hi, Royuk

Thanks for the below code or link

But.....

The procedure below is for USA-style dates (mm dd yyyy format). but in my excel date format is in European style dates (dd mm yyyy)

Code

Private Sub Worksheet_Change(ByVal Target As Excel.Range)

Dim DateStr As String

On Error GoTo EndMacro
If Application.Intersect(Target, Range("A1:A10")) Is Nothing Then
    Exit Sub
End If
If Target.Cells.Count > 1 Then
    Exit Sub
End If
If Target.Value = "" Then
    Exit Sub
End If

Application.EnableEvents = False
With Target
If .HasFormula = False Then
    Select Case Len(.Formula)
        Case 4 ' e.g., 9298 = 2-Sep-1998
            DateStr = Left(.Formula, 1) & "/" & _
            Mid(.Formula, 2, 1) & "/" & Right(.Formula, 2)
        Case 5 ' e.g., 11298 = 12-Jan-1998 NOT 2-Nov-1998
            DateStr = Left(.Formula, 1) & "/" & _
                Mid(.Formula, 2, 2) & "/" & Right(.Formula, 2)
        Case 6 ' e.g., 090298 = 2-Sep-1998
            DateStr = Left(.Formula, 2) & "/" & _
                Mid(.Formula, 3, 2) & "/" & Right(.Formula, 2)
        Case 7 ' e.g., 1231998 = 23-Jan-1998 NOT 3-Dec-1998
            DateStr = Left(.Formula, 1) & "/" & _
                Mid(.Formula, 2, 2) & "/" & Right(.Formula, 4)
        Case 8 ' e.g., 09021998 = 2-Sep-1998
            DateStr = Left(.Formula, 2) & "/" & _
                Mid(.Formula, 3, 2) & "/" & Right(.Formula, 4)
        Case Else
            Err.Raise 0
    End Select
    .Formula = DateValue(DateStr)
End If

End With
Application.EnableEvents = True
Exit Sub
EndMacro:
MsgBox "You did not enter a valid date."
Application.EnableEvents = True
End Sub

Display More

I try to convert the DateStr (European style dates format) using the below code

Code

datestr(datenum(dd-mm-yy),formatOut)

But It doesn't work.

Can Someone give suggestions on what to change and where to change in the code?

Thanks in advance.

**royUK** · Sep 15th 2021

I haven't looked at this for some time

Try this

Code

.Formula = Format(DateValue(DateStr), "dd/mm/yyyy")

mamun.ges · Sep 15th 2021

Hi,

It works.

Thanks, RoyUK .

**royUK** · Sep 16th 2021

Pleased to help

Typed number auto convert as date

Participate now!

Share

Tags