Hi All
I have a couple of renders of signitures which I would like to put insert "In Front Of Text" on various word documents.
Is there a VBA code that I could put into the Normal.doc as a Macro that just inserts a picture (via the file path/name) onto of a documents?
Thanks
Re: Word VBA to insert pictures (from file) "In Front Of Text"
You don't really give enough info, but the following will display a dialogue to select a picture and insert to a bookmark. This can easily be changed to determine a name from the logged in user and insert at the current insertion point (That's where your post is not clear).
Sub Test()
Dim strPicName As String
Dim vShape As InlineShape
Dim Rng As Range
With Application.Dialogs(wdDialogInsertPicture)
If .Show = -1 Then
strPicName = .Name
With ActiveDocument
Set Rng = .Bookmarks("PicHere").Range
Rng.Text = vbNullString
Set vShape = .InlineShapes.AddPicture(FileName:=strPicName, LinkToFile:=False, Range:=Rng)
With vShape
.LockAspectRatio = True
.Height = InchesToPoints(1)
End With
With Rng
.End = .End + 1
End With
.Bookmarks.Add "PicHere", Rng
End With
End If
End With
End SubThe macro can be linked to a button or hot-key.
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Sorry for not being clear.
Basically I have three rendered signitures for three users, the users will open up a document, and then they need to put their signiture on it and save it. This is to save them printing it out just to sign and then scanning back in.
Since its such a simple step I wasn't going to bother to code the whole thing. Was just after a macro to insert a picture anywhere on the document as it doesn't matter cause the user will move it around to where they want it anyway. But its needs to be in front of text (so that by moving it, it doesn't mess up the document).
There are only three picture files so I was going to just hard code the picture paths in, and then assign a shortcut key so user A would simply go Ctrl+Shift+A for his, and User B would go Ctrl+Shift+B for his etc?
Re: Word VBA to insert pictures (from file) "In Front Of Text"
You could name the sigs same as the user name, and then using, along with other code, the
command insert the appropriate sig at the current insertion point. Only one procedure that way.
Sorry about the OTT sample, getting the pic using the dialogue was just an example. The bookmark can be ignored as well if you're happy to insert where the cursor is.
Re: Word VBA to insert pictures (from file) "In Front Of Text"
I happy to insert anywhere, as the user will have to move it around to find a blank ish part of the page anyway. Even though they are renders its still better to put them over a blank ish part. I could certainly save them under the user name and use that code that would be great.
The code I need though is just the insert from file code? I have no idea how to write this?
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Slightly modified... To insert a picture named as <USERNAME>.jpg at the current insertion point:
Sub Test()
Dim rng As Range
Dim vShape As InlineShape
'// Remember where the cursor is...
Set rng = Selection.Range
'// Add the picture - change hard-coded directory to suit.
Set vShape = Selection.InlineShapes.AddPicture(FileName:="C:\Temp\" & Environ("UserName") & ".jpg", LinkToFile:= _
False, SaveWithDocument:=True)
'// Resize. LockAspectRation maintains the aspect
'// This example makes it 1 inch high - you might prefer it smaller
With vShape
.LockAspectRatio = True
.Height = InchesToPoints(1)
End With
'// Move the cursor over 1 character...
With rng
.End = .End + 1
End With
End SubThe ENVIRON() command returns the logged in user name...
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Awesome thanks, is there a code to make in "In Front of Text" so it can be moved around freely without messing up the document?
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Add 2 lines after the 'With vShape' statement
With vShape
.Select
Selection.ShapeRange.WrapFormat.Type = wdWrapFront
.LockAspectRatio = True
.Height = InchesToPoints(1)
End With*EDIT*
On second thoughts, it really should have error handling - the file just may not exist or is corrupt (Not an unknown thing to happen!)...
Complete revised code:
Sub Z()
'// Change to suit. Must have the trailing \
Const cStrDIR As String = "C:\TEMP\"
Dim rng As Range
Dim vShape As InlineShape
On Error GoTo ErrHandler
'// Remember where the cursor is...
Set rng = Selection.Range
'// Add the picture
Set vShape = Selection.InlineShapes.AddPicture(FileName:=cStrDIR & Environ("UserName") & ".jpg", LinkToFile:= _
False, SaveWithDocument:=True)
'// Resize. LockAspectRation maintains the aspect
'// This example makes it 1 inch high - you might prefer it smaller
With vShape
.Select
Selection.ShapeRange.WrapFormat.Type = wdWrapFront
.LockAspectRatio = True
.Height = InchesToPoints(1)
End With
'// Move the cursor over 1 character...
With rng
.End = .End + 1
End With
Exit Sub
ErrHandler:
If Err.Number = 5152 Then
MsgBox "The sig file '" & cStrDIR & UCase$(Environ("UserName")) & ".JPG' does not exist. Cannot add signature.", vbExclamation, "Not found"
ElseIf Err.Number = 5382 Then
MsgBox "The sig file '" & cStrDIR & UCase$(Environ("UserName")) & ".JPG' has an invalid format.", vbExclamation, "Invalid file"
Else
MsgBox "General error: " & Err.Description, vbExclamation, "Error"
End If
End SubRe: Word VBA to insert pictures (from file) "In Front Of Text"
Thanks cytop, I think its getting close
But the code fails at:
Selection.ShapeRange.WrapFormat.Type = wdWrapFront
With a run time 4198 command failed error?
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Sorry - I can't replicate that.
Error 4198 seems to be some sort of timing or synchronisation error. Can only suggest the following to pause processing and allow Word to 'catch up'
With vShape
.Select
DoEvents: DoEvents
Selection.ShapeRange.WrapFormat.Type = 3 'wdWrapFront
.LockAspectRatio = True
.Height = InchesToPoints(1)
End WithSorry I can't be more precise. I'll have a closer look when I have time later.
Re: Word VBA to insert pictures (from file) "In Front Of Text"
When you set the picture as in front of text manually it opens up the "Horizontal Alignment" options perhaps that needs to be set also?
I tried the above but it still gets the 4198 error on the same line.
I found this article on the error:
http://support.microsoft.com/d…spx?scid=kb;en-us;Q228701
Which sort of makes sense, as the picture is being selected... But I cant see any hyperlink objects in the code and there are no hyperlinks (as I know them) on the document?
Sorry, I have it working now... I opened one of the docs and noticed it was running in Compatibility Mode, so I went to File then converted to current format, saved and reopened... And now the code above works perfectly. Dont know if this can help you figure out why it would make a difference.
Cheers though big help.
Re: Word VBA to insert pictures (from file) "In Front Of Text"
Quote from cytop;680650Sorry - I can't replicate that.
Many Thanks, let me suggest to include .ConvertToShape in order to float the image "In Front Of Text"
I'm using this to insert a image stamp with transparent background
HeightOfImage = InchesToPoints(1)
With vShape
'resize the image
H = .Height
B = .Width
Ratio = H / B
.Height = HeightOfImage
.Width = HeightOfImage / Ratio
'Transparent background
.PictureFormat.TransparentBackground = msoTrue
.PictureFormat.TransparencyColor = RGB(255, 255, 255)
.Fill.Visible = msoFalse
'In Front Of Text
.ConvertToShape
End WithDon’t have an account yet? Register yourself now and be a part of our community!