Help concatenating cells from column of variable number of rows based upon common id

I regularly need to concatenate the fields from two columns based upon the id in another column. The rows will vary in the control column.
For example:

ID Qty Item
1 Recipe Name
1 1 Roses
1 2 Daisy
1 7 Orchid
2 Other Recipe Name
2 1 Daisy
2 6 Mum
2 2 Rose
2 4 Rose
2 1 Carnation
2 1 Fern
3 Yet Another Recipe Name
3 6 Orchid
3 2 Mums

I need the data to end up like this. Ideally the result would strip out the Recipe Name which heads each set of records with the same control number.
If not possible to strip out the recipe name I can manually do that.

ID Data
1 1 Rose |2 Daisy |7 Orchid
2 1 Daisy |6 Mum |2 Rose |4 Rose |1 Carnation |1 Fern
3 6 Orchids |2 Mums

Re: Help concatenating cells from column of variable number of rows based upon common

Quote from jindon;680625

Try

Code

Sub test()
    Dim a, i As Long, n As Long, w
    a = Cells(1).CurrentRegion.Value
    With CreateObject("Scripting.Dictionary")
        .CompareMode = 1
        For i = 2 To UBound(a, 1)
            If a(i, 3) <> "" Then
                If Not .exists(a(i, 1)) Then
                    n = n + 1: .Item(a(i, 1)) = VBA.Array(n, 2)
                    a(n, 1) = a(i, 1): a(n, 2) = a(i, 2) & " " & a(i, 3)
                    a(i, 3) = ""
                Else
                    w = .Item(a(i, 1)): w(1) = w(1) + 1
                    If UBound(a, 2) < w(1) Then
                        ReDim Preserve a(1 To UBound(a, 1), 1 To w(1))
                    End If
                    a(w(0), w(1)) = a(i, 2) & " " & a(i, 3): a(i, 3) = ""
                    .Item(a(i, 1)) = w
                End If
            End If
        Next
    End With
    With Sheets.Add.Cells(1).Resize(n, UBound(a, 2))
        .Value = a
        .Columns.AutoFit
    End With
End Sub

Display More

Thanks, this worked for me. I really appreciate the help!