open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Manager

Re: open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Mana

Try setting the Objects to Nothing.

Basically:

Set xlApp = Nothing

at the end of the procedure, and include extra lines for anything that was assigned using the SET keyword...

Not saying it's a fix, but it should be done in any case.

Re: open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Mana

You have lots of unqualified object references in there:

'take counts of Orders (in textboxes) and copy to predetermined xls
'open excel from outlook, take counts from public folders,
'leave Excel open for user to work in (user closes Excel and goes back to
'Outlook, etc.


   Dim xlApp                       As Object
   Dim sourceWB                    As Workbook
   Dim sourceSH                    As Worksheet


   Set xlApp = CreateObject("Excel.Application")


   With xlApp
      .Visible = True
      .EnableEvents = False
   End With


   strFile = "C:\temp\ex_with_Outlook.xlsx"


   Set sourceWB = xlApp.Workbooks.Open(strFile, , False, , , , , , , True)
   Set sourceSH = sourceWB.Worksheets("OF")
   With sourceSH
      With .Cells(.Rows.Count, 1).End(xlUp).Offset(1)
         .Value = Now()
         .Offset(0, 1).Value = txtInboxTodaysDate
         .Offset(0, 2).Value = txtIDeletedToday
         .Offset(0, 3).Value = txtIDeletedYesterday
      End With
   End With
   'keep workbook open for user to peruse, etc.

Re: open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Mana

You were referring simply to

ActiveCell = Now() 
ActiveCell.Offset(0, 1).Value = txtInboxTodaysDate

which, on the face of it, is fine except the sheet that will be updated is whatever is active at the time the code runs. See Rorys' revised code for a fix.

Yes, you can set an instance of an object to Nothing in your code, Excel will continue to run as you never told it to quit. Also, it is visible so the user can quit when needed.

Re: open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Mana

For example, in this line:

Set sourceWB = Workbooks.Open(strFile, , False, , , , , , , True)

you have not qualified the Workbooks property with xlApp so you are creating an implicit Excel object reference that you can't destroy, which is why you end up with the orphaned processes. It should be:

Set sourceWB = xlApp.Workbooks.Open(strFile, , False, , , , , , , True)

Same thing with your use of Range and Activecell.

Re: open Excel from Outlook-upon close, Excel still listed in Processes tab-Task Mana

Quote

... implicit Excel object reference that you can't destroy

We all learn...