Macro that counts all characters in Worksheet

7absinth · Mar 23rd 2016

I googled very many pages and forums, but I found nothing. So I am tryin to find VBA but I cant find my luck to resolve it:

So what wrong with this code. Code must to show me message box that counts all characters in worksheet.

Code

Sub countchar()


MsgBox Application.WorksheetFunction.SumProduct(Len(ActiveSheet.UsedRange))




End Sub

SumProduct(len(range)) is no macro solution but it doesnt work because of sumproduct expression in VBA...I dont know what should to do to figure out how to run this.

mohammedismail · Mar 24th 2016

Re: Macro that counts all characters in Worksheet

Check out this, may be it gives more information than you need !

Code

Sub CountCharacters()    
    Dim wks As Worksheet
    Dim rng As Range
    Dim rCell As Range
    Dim shp As Shape




    Dim bPossibleError As Boolean
    Dim bSkipMe As Boolean




    Dim lTotal As Long
    Dim lTotal2 As Long
    Dim lConstants As Long
    Dim lFormulas As Long
    Dim lFormulaValues As Long
    Dim lTxtBox As Long
    Dim sMsg As String




    On Error GoTo ErrHandler
    Application.ScreenUpdating = False




    lTotal = 0
    lTotal2 = 0
    lConstants = 0
    lFormulas = 0
    lFormulaValues = 0
    lTxtBox = 0
    bPossibleError = False
    bSkipMe = False
    sMsg = ""




    For Each wks In ActiveWorkbook.Worksheets
        ' Count characters in text boxes
        For Each shp In wks.Shapes
            If TypeName(shp) <> "GroupObject" Then
                lTxtBox = lTxtBox + shp.TextFrame.Characters.Count
            End If
        Next shp




        ' Count characters in cells containing constants
        bPossibleError = True
        Set rng = wks.UsedRange.SpecialCells(xlCellTypeConstants)
        If bSkipMe Then
            bSkipMe = False
        Else
            For Each rCell In rng
                lConstants = lConstants + Len(rCell.Value)
            Next rCell
        End If




        ' Count characters in cells containing formulas
        bPossibleError = True
        Set rng = wks.UsedRange.SpecialCells(xlCellTypeFormulas)
        If bSkipMe Then
            bSkipMe = False
        Else
            For Each rCell In rng
                lFormulaValues = lFormulaValues + Len(rCell.Value)
                lFormulas = lFormulas + Len(rCell.Formula)
            Next rCell
        End If
    Next wks




    sMsg = Format(lTxtBox, "#,##0") & _
      " Characters in text boxes" & vbCrLf
    sMsg = sMsg & Format(lConstants, "#,##0") & _
      " Characters in constants" & vbCrLf & vbCrLf




    lTotal = lTxtBox + lConstants




    sMsg = sMsg & Format(lTotal, "#,##0") & _
      " Total characters (as constants)" & vbCrLf & vbCrLf




    sMsg = sMsg & Format(lFormulaValues, "#,##0") & _
      " Characters in formulas (as values)" & vbCrLf
    sMsg = sMsg & Format(lFormulas, "#,##0") & _
      " Characters in formulas (as formulas)" & vbCrLf & vbCrLf




    lTotal2 = lTotal + lFormulas
    lTotal = lTotal + lFormulaValues




    sMsg = sMsg & Format(lTotal, "#,##0") & _
      " Total characters (with formulas as values)" & vbCrLf
    sMsg = sMsg & Format(lTotal2, "#,##0") & _
      " Total characters (with formulas as formulas)"




    MsgBox Prompt:=sMsg, Title:="Character count"




ExitHandler:
    Application.ScreenUpdating = True
    Exit Sub




ErrHandler:
    If bPossibleError And Err.Number = 1004 Then
        bPossibleError = False
        bSkipMe = True
        Resume Next
    Else
        MsgBox Err.Number & ": " & Err.Description
        Resume ExitHandler
    End If
End Sub

Display More

Source

7absinth · Mar 24th 2016

Re: Macro that counts all characters in Worksheet

Wow. It is more than I expected. Looks like in Word now. :angrypc: BIG thank you. It was really helpful. :wowee:

mohammedismail · Mar 24th 2016

Re: Macro that counts all characters in Worksheet

Glad to have helped you! Sometimes googling helps

7absinth · Mar 24th 2016

Re: Macro that counts all characters in Worksheet

But I suddenly got error message..maybe it doesnt count activex button characters.

Error:
438: Object doesn't support this property or method.

Macro that counts all characters in Worksheet

Participate now!

Share