Userform Text Transfer in Bold and Underlined

Re: Userform Text Transfer in Bold and Underlined

You cannot change the attributes of part of the text in a textbox, it's all or nothing so setting the text bold will have to be done after the sheet is updated.

Add to a standard code module

Sub BoldWord(ByVal r As Excel.Range, ByVal strWord As String)
   
   Dim c As Excel.Range
   
   For Each c In r
      
      If InStr(c.Text, strWord) > 0 Then
         c.Characters(Start:=InStr(1, c.Text, strWord), Length:=Len(strWord)).Font.Bold = True
      End If
   Next
   
End Sub

Transfer the text as now then call the procedure. This can handle either single cells or a range of cells so how you do it is down to you.

Cells(emptyRow, 5).Value = "RISK:" & Chr(10) & Identification.Value & " " & Chr(10) & "IMPACT:" & Chr(10) & Impact.Value 
    BoldWord Cells(emptyRow, 5), "RISK"
    BoldWord Cells(emptyRow, 5), "IMPACT"

Note that VBA is Case Sensitive by default, unless you are using

Option Compare Text

in the General Declarations section then make sure case matches.

Re: Userform Text Transfer in Bold and Underlined

Glad it worked for you.

Just as an example, I've modified it a little. The updated version will set the text attributes for Bold, UnderLined or Italicised, and can be used to add or remove those attributes

' In the General Declarations section of the module
Public Enum FontAttr
   Bold = 1
   Italic = 2
   Underline = 4
End Enum




Sub FormatWord(ByVal r As Excel.Range, ByVal strWord As String, NewAttr As FontAttr, Optional TurnOn As Boolean = True)
   
   Dim c As Excel.Range
   Dim lngStartPos As Long
   
   For Each c In r
      
      lngStartPos = InStr(c.Text, strWord)
      
      If lngStartPos > 0 Then
      
         If NewAttr And Bold Then
            c.Characters(Start:=lngStartPos, Length:=Len(strWord)).Font.Bold = TurnOn
         End If
         If NewAttr And Italic Then
            c.Characters(Start:=lngStartPos, Length:=Len(strWord)).Font.Italic = TurnOn
         End If
         If NewAttr And Underline Then
            c.Characters(Start:=lngStartPos, Length:=Len(strWord)).Font.Underline = TurnOn
         End If
      
      End If
   Next
   
End Sub

You can combine the elements of the Enum (Bold, Italic & UnderScore). Sample calls:

Underline & Bold the word 'Risk' ('True' is a default and can be omitted)[INDENT]FormatWord Cells(emptyRow, 5), "RISK", UnderLine + Bold, True [/INDENT]

Turn off Italics, Bold & Underline for the word 'Risk'[INDENT]FormatWord Cells(emptyRow, 5), "RISK", Italic + UnderLine + Bold, False[/INDENT]

Re: Userform Text Transfer in Bold and Underlined

Any mix of 1, 2 or all 3
Italic + UnderLine + Bold
Underline + Bold
Italic