Label caption doesn't display on userform after update using Class modules

tienphamsd · Jan 24th 2017

Hello,

I have a userform that will have multiple text boxes for users to edit data pulled from one of the Sheets.
In that userform I have corresponding labels for each text box to show the number of characters each has.
I want each respective label to update their caption to be displayed as the user is editing each text box.

The method I have come across to do this is by using a Class module.
However, I am having an issue with the label caption not displaying on the userform.
The below code is an example of the code I'm using on just a single text box and single corresponding label named ItemNumber and ItemNumberLength respectively:

Class Module:

Code

Private WithEvents MyTextBox As MSForms.TextBox




Public Property Set Control(tb As MSForms.TextBox)
    Set MyTextBox = tb
End Property




Private Sub MyTextBox_Change()
    
    Call Userform1.PersistentUpdate_ItemNumber
    
End Sub

Display More

Userform1:

Code

Dim tbCollection As Collection


Private Sub UserForm_Initialize()
    
    Dim ctrl As MSForms.Control
    Dim obj As clsTextBox




    Set tbCollection = New Collection
        For Each ctrl In Me.Controls
                If TypeOf ctrl Is MSForms.TextBox Then
                    Set obj = New clsTextBox
                    Set obj.Control = ctrl
                    tbCollection.Add obj
                End If
        Next ctrl
    Set obj = Nothing


End Sub


Public Sub PersistentUpdate_ItemNumber()


    ItemNumberLength.Caption = Len(ItemNumber.Text)


End Sub

Display More

Thanks in advance!

Logit · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

.
If I correctly understand your question, you can simplify your efforts with :

Code

Option Explicit


Private Sub TextBox1_Change()
    Label1.Caption = TextBox1.Text
End Sub

tienphamsd · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

Hi Logit. Thanks for the reply.
Unfortunately that only works if I write that code for every textbox I would have in the userform. So if I had say 20 textboxes, I would have to include a sub for each of them. Creating the Class module eases that as it let's me use just a few lines of code to step thru all of the textboxes at once. It seems to work as when I include a MsgBox, that pops up every time I make a change in the textboxes. So, I know that it calls the sub PersistentUpdate_ItemNumber()...there just seems to be a problem with it displaying the caption after it's changed.

**pike** · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

Hi '
Possibly with your code
Class module named clsTextBox

Code

Option Explicit
Private WithEvents MyTextBox As MSForms.TextBox
 
Public Property Set Control(tb As MSForms.TextBox)
Set MyTextBox = tb
End Property
 
Private Sub MyTextBox_Change()
    Call UserForm1.PersistentUpdate_ItemNumber(MyTextBox.Name)
End Sub

and in the userform1 module

Code

Option Explicit
Dim tbCollection As Collection


Private Sub UserForm_Initialize()
     
    Dim ctrl As MSForms.Control
    Dim obj As clsTextBox


    Set tbCollection = New Collection
    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox Then


            Set obj = New clsTextBox
            Set obj.Control = ctrl
            tbCollection.Add obj
        End If
    Next ctrl
    Set obj = Nothing
     
End Sub
 
Sub PersistentUpdate_ItemNumber(MyName As String)
  Dim myIndex As Long
  myIndex = Right(MyName, Len(MyName) - 7)
  Me("Label" & myIndex).Caption = Len(Me(MyName).Text)
     
End Sub

Display More

Logit · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

Change the Sub to:

Code

Sub PersistentUpdate_ItemNumber(MyName As String)
    Dim myIndex As Long
    myIndex = Right(MyName, Len(MyName) - 7)
    Me("Label" & myIndex).Caption = Me("Textbox" & myIndex).Text
End Sub

Thanks Pike !

tienphamsd · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

Hmm...I seem to be having an issue passing in the MyTextBox.Name
It keeps giving me a Type Mismatch error?

Logit · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

.
At first, had same issue. My solution was overlooked in his post.

Quote

Class module named clsTextBox

Rename the Class Module to ' clsTextBox ' . I had to try that several times for some reason, until it finally took hold.

tienphamsd · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

Thanks Logit and Pike for your input!
I finally got it to work by just starting from scratch again.

However, when I tried to reuse it in the workbook I've been working on it went right back to the same problem I was previously having. That is that the Label caption wasn't displaying on the UserForm.
So, I apparently was having two separate issues...

For the sake of other readers, so that they don't make the same mistake I did.
I found the second issue to be in how I was calling the userform. I originally had a button on the worksheet that called a macro to run various other tasks before it called the userform.

I don't recall why I originally wrote it this way, but the example below shows how I was calling it...as opposed to the much simpler way that actually works properly:

(Doesn't work)

Code

Sub RunUserFrom()        
	Dim myUserform As UserForm1
        Set myUserform = New UserForm1
        myUserform.Show
End Sub

(Does Work)

Code

Sub RunUserForm()        
	UserForm1.Show
End Sub

Thanks again both for helping me figure this out! I've been banging my head against the wall over this for days now...Haha.

Logit · Jan 24th 2017

Re: Label caption doesn't display on userform after update using Class modules

You're welcome. Glad to help. I learned alot from your post as well.

**pike** · Jan 27th 2017

Re: Label caption doesn't display on userform after update using Class modules

Hello,
some alternate methods that may help; located here
http://www.ozgrid.com/forum/sh…96122&p=755240#post755240

**rory** · Jan 27th 2017

Re: Label caption doesn't display on userform after update using Class modules

FWIW, I would suggest you add a label variable to the class and simply refer to that:

Code

Private WithEvents MyTextBox As MSForms.TextBox
Private lbl As MSForms.Label
 
Public Property Set Control(tb As MSForms.TextBox)
Set MyTextBox = tb
End Property
Public Property Set Label(lb As MSForms.Label)
Set lbl = lb
End Property
 
 
Private Sub MyTextBox_Change()
     
    lbl.Caption = Len(MyTextBox.Text)
     
End Sub

Display More

and then something like this:

Code

Dim tbCollection As Collection
 
Private Sub UserForm_Initialize()
     
    Dim ctrl As MSForms.Control
    Dim obj As clsTextBox
     
     
    Set tbCollection = New Collection
    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox Then
            Set obj = New clsTextBox
            Set obj.Control = ctrl
            Set obj.Label = Me.Controls(ctrl.Name & "Length")
            tbCollection.Add obj
        End If
    Next ctrl
    Set obj = Nothing
     
End Sub

Display More

**pike** · Jan 27th 2017

Re: Label caption doesn't display on userform after update using Class modules

Cool

class code

Code

Option Explicit
Private WithEvents MyTextBox As MSForms.TextBox
Private lbl As MSForms.label
Public Property Set Control(tb As MSForms.TextBox)
    Set MyTextBox = tb
End Property
Public Property Set label(lb As MSForms.label)
    Set lbl = lb
End Property
Private Sub MyTextBox_Change()
    lbl.Caption = MyTextBox.Text
End Sub

Display More

enhancement to userform code

Code

Option Explicit
Dim tbCollection As Collection


Private Sub UserForm_Initialize()
     
    Dim ctrl As MSForms.Control
    Dim obj As clsTextBox


    Set tbCollection = New Collection
    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox Then
            Set obj = New clsTextBox
            Set obj.Control = ctrl
            Set obj.label = Me.Controls(Replace(ctrl.Name, "TextBox", "Label"))
            tbCollection.Add obj
        End If
    Next ctrl
    Set obj = Nothing
     
End Sub

Display More

Label caption doesn't display on userform after update using Class modules

Participate now!

Share

Users Viewing This Thread