Find correct tab in Internet Explorer and activate it

Bundi · May 19th 2017

Hi,

I need to find a specific tab in an open instance in Internet Explorer. I found a macro to bring Internet Explorer to the front, but then I need to find a specific tab and then activate it.
I have found macros that can verify that the tab is open, but I haven't managed to merge any of those codes into the macro I have for bringing IE to the front.

This is the macro I have for bringing IE to the front:
(Found at "Happy Codings" site)

Code

Option Explicit 
 
 
 
 
Private Type POINTAPI 
    x As Long 
    y As Long 
End Type 
 
 
Private Type RECT 
    Left As Long 
    Top As Long 
    Right As Long 
    Bottom As Long 
End Type 
Private Type WINDOWPLACEMENT 
    Length As Long 
    flags As Long 
    showCmd As Long 
    ptMinPosition As POINTAPI 
    ptMaxPosition As POINTAPI 
    rcNormalPosition As RECT 
End Type 
 
 
Private Declare Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long 
Private Declare Function GetWindowPlacement Lib "user32" (ByVal hwnd As Long, lpwndpl As WINDOWPLACEMENT) As Long 
Private Declare Function SetWindowPlacement Lib "user32" (ByVal hwnd As Long, lpwndpl As WINDOWPLACEMENT) As Long 
Private Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long 
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long 
Public Const SW_MINIMIZE = 6, SW_NORMAL = 1, SW_MAXIMIZE = 3, SW_RESTORE = 9 
 
 
 
 
 '-------METHOD 1--------------
 
 
 'Purpose   :    Brings the specified application to foreground and alters it's window state.
 'Inputs    :    [sFormCaption]                  The caption of the dialog to bring to the foreground.
 '               OR
 '               [lHwnd]                         The window handle of the dialog to bring to the foreground.
 '               [lWindowState]                  Specifies the windowstate of the application (defaults to normal)
 'Outputs   :    Returns True on success
 'Notes     :    Specify either the application caption or it's windows handle
 'Revisions :
 
 
Function AppToForeground(Optional sFormCaption As String, Optional lHwnd As Long, Optional lWindowState As Long = SW_NORMAL) As Boolean 
    Dim tWinPlace As WINDOWPLACEMENT 
     
     
    If lHwnd = 0 Then 
        lHwnd = DialogGetHwnd(sFormCaption) 
    End If 
    If lHwnd Then 
        tWinPlace.Length = Len(tWinPlace) 
         'Get the windows current placement
        Call GetWindowPlacement(lHwnd, tWinPlace) 
         'Set the windows placement
        tWinPlace.showCmd = lWindowState 
         'Change window state
        Call SetWindowPlacement(lHwnd, tWinPlace) 
         'Bring to foreground
        AppToForeground = SetForegroundWindow(lHwnd) 
    End If 
End Function 
 
 
 
 
 '-------METHOD 2--------------
 
 
 'Purpose   :    Brings the specified application to foreground and alters it's window state.
 'Inputs    :    [sApplicationCaption]           The application caption.
 '               [lHwnd]                         The handle to the application.
 '               [lWindowState]                  Specifies the windowstate of the application (defaults to normal)
 'Outputs   :    Returns True on success
 'Notes     :    Specify either the application caption or it's windows handle
 'Revisions :
 
 
Function AppToForeground2(Optional sApplicationCaption As String, Optional lHwnd As Long, Optional lWindowState As Long = SW_NORMAL) As Boolean 
     
     
     
    If lHwnd = 0 Then 
        lHwnd = DialogGetHwnd(sApplicationCaption) 
    End If 
    If lHwnd Then 
         'Alter window state
        AppToForeground2 = ShowWindow(lHwnd, lWindowState) 
         'Bring to foreground
        AppToForeground2 = SetForegroundWindow(lHwnd) 
    End If 
End Function 
 
 
 
 
 'Demonstration routine, brings Excel to foreground and maximises it
Sub Test() 
    Dim lHwnd As Long 
     
     'Get IE's handle
    lHwnd = DialogGetHwnd(, "IEFrame") 
    If lHwnd Then 
        If AppToForeground(, lHwnd, SW_MAXIMIZE) Then 
            MsgBox "Maximized IE", vbSystemModal 
        Else 
            MsgBox "Failed to Maximised IE", vbSystemModal 
        End If 
    Else 
        MsgBox "Please open IE before trying this demonstration" 
    End If 
End Sub 
 
 
 
 
 'Purpose   :    Returns the Windows Handle of a Dialog based on its caption.
 'Inputs    :    [sDialogCaption]                The dialog caption.
 '               [sClassName]                    The class name of the dialog. If unknown, do not specify
 '                                               this parameter.
 'Outputs   :    The Dialogs Window Handle
 'Notes     :    Specify either a dialog caption or class name or both.
 'Revisions :
 
 
Function DialogGetHwnd(Optional ByVal sDialogCaption As String = vbNullString, Optional sClassName As String = vbNullString) As Long 
    On Error Resume Next 
    DialogGetHwnd = FindWindowA(sClassName, sDialogCaption) 
    On Error GoTo 0 
End Function

Display More

I have seen some codes that uses SendKeys, but I would prefer to avoid that. And instead somehow loop through the names of the tabs to locate the correct one.

I have also posted the question some time ago here:
http://www.vbaexpress.com/foru…ance-of-Internet-Explorer

Thank you,
Bundi

John_w · May 29th 2017

Re: Find correct tab in Internet Explorer and activate it

Try this code, which uses the CUIAutomation class to activate the required IE tab. This works on IE9 and higher.

You must set the references noted at the top of the code: Tools -> References in the VBA editor.

Code

Option Explicit


'References
'Microsoft Internet Controls
'Microsoft Shell Controls and Automation
'UIAutomationClient


Public Sub Test()


    Dim IE As InternetExplorer
       
    Set IE = Find_and_Activate_IE_Tab("*ozgrid*")
    If Not IE Is Nothing Then
        MsgBox "Found IE tab" & vbNewLine & _
               "LocationURL = " & IE.LocationURL & vbNewLine & _
               "LocationName = " & IE.LocationName
    Else
        MsgBox "Not found IE tab"
    End If


End Sub




Private Function Find_and_Activate_IE_Tab(TitleOrURL As String) As InternetExplorer


    'Look for an IE browser window or tab which matches the specified title or URL (Like operator wildcards allowed).
    'If found, activate that IE tab and return it as an InternetExplorer object.  Otherwise return Nothing.


    Dim Shell As Shell
    Dim IE As InternetExplorer
    Dim i As Variant        'must be a variant to access items in Shell.Windows() array
    
    Set Shell = New Shell


    i = 0
    Set Find_and_Activate_IE_Tab = Nothing
    While i < Shell.Windows.Count And Find_and_Activate_IE_Tab Is Nothing
        Set IE = Shell.Windows(i)
        If Not IE Is Nothing Then
            If TypeName(IE.Document) = "HTMLDocument" Then
                If LCase(IE.LocationURL) Like LCase(TitleOrURL) Or LCase(IE.LocationName) Like LCase(TitleOrURL) Then
                    
                    'Found the required IE tab.  Now make it the active tab
                    
                    UIAutomation_Click_IE_Tab IE.hwnd, IE.LocationName
                    Set Find_and_Activate_IE_Tab = IE
                End If
            End If
        End If
        i = i + 1
    Wend
    
End Function




#If VBA7 Then
Private Sub UIAutomation_Click_IE_Tab(IEhwnd As LongPtr, TabName As String)
#Else
Private Sub UIAutomation_Click_IE_Tab(IEhwnd As Long, TabName As String)
#End If
   
    'Find and click the specified IE tab name using UIAutomation
    
    Dim UIauto As IUIAutomation
    Dim IEwindow As IUIAutomationElement, IEtab As IUIAutomationElement
    Dim tabItemCondition As IUIAutomationCondition, tabNameCondition As IUIAutomationCondition, tabItemAndName As IUIAutomationCondition
    Dim IEtabPattern As IUIAutomationLegacyIAccessiblePattern
    
    'Create UIAutomation object
    
    Set UIauto = New CUIAutomation
            
    'Get Internet Explorer UIAutomation element
    
    Set IEwindow = UIauto.ElementFromHandle(ByVal IEhwnd)
    
    'Create conditions to find the child tab element (a TabItemControl with the specific tab name) of the IE window element.
    'Note that the maximum length of the Name property for a TabItemControl seems to be 127, therefore only the
    'first 127 characters of the required tab name is specified for the UIA_NamePropertyId condition
    
    Set tabItemCondition = UIauto.CreatePropertyCondition(UIA_ControlTypePropertyId, UIA_TabItemControlTypeId)
    Set tabNameCondition = UIauto.CreatePropertyCondition(UIA_NamePropertyId, Left(TabName, 127))
    Set tabItemAndName = UIauto.CreateAndCondition(tabItemCondition, tabNameCondition)
    
    'Find first matching tab
    
    Set IEtab = IEwindow.FindFirst(TreeScope_Descendants, tabItemAndName)
        
    'Access the legacy pattern of the IE tab, which has the DoDefaultAction method (Click)
    
    Set IEtabPattern = IEtab.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)
    IEwindow.SetFocus   'optional - brings the IE window to the foreground
    IEtabPattern.DoDefaultAction
        
    Set UIauto = Nothing
    
End Sub

Display More

Bundi · May 30th 2017

Re: Find correct tab in Internet Explorer and activate it

Thank you John for the code.

I tried it in my intended application, but I get "Run Time Error '91': Object variable or With block variable not set " and it points to this line

Code

Set IEtabPattern = IEtab.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)

This I got after changing the IE tab name (ozgrid) to the page I need in this line

Code

Set IE = Find_and_Activate_IE_Tab("*ozgrid*")

When trying to run it without changing the IE tab name, I get this error "Run-time error '-2147467259 (80004005)'" Automation error Unspecified error.

And when doing debug, it points to this line

Code

If TypeName(IE.document) = "HTMLDocument" Then

Not sure really what is causing it.
Thanks for your help

John_w · May 31st 2017

Re: Find correct tab in Internet Explorer and activate it

Try changing all occurrences of "As InternetExplorer" to "As InternetExplorerMedium".

Which Windows OS and IE version are you running?

Oliv- · Apr 17th 2018

With IE11 you need to change the call to

Code

Dim Tabname
Tabname= IE.Document.Title
If Tabname= "" Then Tabname= IE.Document.Location.hostname


Call UIAutomation_Click_IE_Tab(IE.hwnd, Tabname)

John_w · Apr 19th 2018

Quote from Oliv-

With IE11 you need to change the call to

Code

Dim Tabname
Tabname= IE.Document.Title
If Tabname= "" Then Tabname= IE.Document.Location.hostname


Call UIAutomation_Click_IE_Tab(IE.hwnd, Tabname)

In all my tests with IE11 it finds the required tab, which can be specified as the tab's URL or LocationName, including wildcards if needed. Can you give examples of web sites or pages where your change is needed?

John_w · Nov 28th 2018

UPDATE

Recent tests with the UIAutomation_Click_IE_Tab procedure in post #2 generated the error:

Run-time error '91':
Object variable or With block variable not set

At the following line:

Code

Set IEtabPattern = IEtab.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)

The IEtab variable is Nothing because the previous line didn't find the specified tab name.

I discovered that sometimes, although the visible the tab name - shown when hovering over the tab - may be "xxxxx", the actual tab name according to UIAutomation is "xxxxx Tab Group 1". Therefore looking for a tab named "xxxxx" will fail.

The solution is to call UIAutomation_Click_IE_Tab like this:

Code

UIAutomation_Click_IE_Tab IE.hwnd, IE.LocationName & " Tab Group 1"

Alternatively, here is a new procedure which uses the Like operator, so wildcards can be used (see https://docs.microsoft.com/en-us/off.../like-operator) to specify the tab name to be found and activated.

Code

#If VBA7 Then
Private Sub UIAutomation_Click_IE_Tab_Like(IEhwnd As LongPtr, findTabName As String)
#Else
Private Sub UIAutomation_Click_IE_Tab_Like(IEhwnd As Long, findTabName As String)
#End If
  
    Dim UIauto As IUIAutomation
    Dim IEwindow As IUIAutomationElement, IEtab As IUIAutomationElement
    Dim IEtabs As IUIAutomationElementArray
    Dim tabItemCondition As IUIAutomationCondition
    Dim IEtabPattern As IUIAutomationLegacyIAccessiblePattern
    Dim i As Long
    
    'Create UIAutomation object
    
    Set UIauto = New CUIAutomation
    
    'Get Internet Explorer UIAutomation element
    
    Set IEwindow = UIauto.ElementFromHandle(ByVal IEhwnd)
    
    'Create condition to find tab item controls
    
    Set tabItemCondition = UIauto.CreatePropertyCondition(UIA_ControlTypePropertyId, UIA_TabItemControlTypeId)
 
    'Find all tabs
    
    Set IEtabs = IEwindow.FindAll(TreeScope_Descendants, tabItemCondition)
    
    'Look for the tab which matches the specified tab name
    
    Set IEtab = Nothing
    i = 0
    While i < IEtabs.Length And IEtab Is Nothing
        If LCase(IEtabs.GetElement(i).CurrentName) Like LCase(findTabName) Then Set IEtab = IEtabs.GetElement(i)
        i = i + 1
    Wend
        
    If Not IEtab Is Nothing Then
    
        'Access the legacy pattern of the IE tab, which has the DoDefaultAction method (Click), to click the tab
    
        Set IEtabPattern = IEtab.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)
        IEwindow.SetFocus   'optional - brings the IE window to the foreground
        IEtabPattern.DoDefaultAction
    
    Else
    
        MsgBox "IE tab with name '" & findTabName & "' not found"
        
    End If
        
    Set IEtabPattern = Nothing
    Set IEtab = Nothing
    Set IEwindow = Nothing
    Set UIauto = Nothing
    
End Sub

Display More

For example, call it like this:

Code

UIAutomation_Click_IE_Tab_Like IE.hwnd, IE.LocationName & "*"

cnan · Jan 21st 2020

Quote from John_w

In all my tests with IE11 it finds the required tab, which can be specified as the tab's URL or LocationName, including wildcards if needed. Can you give examples of web sites or pages where your change is needed?

Hi John_w,

I try to use your code, but want to select the IE TAB by searching for a LocationURL instead of LocationName.

Unfortunately, I am not able to find the URL equivalent for this property: UIA_NamePropertyId

Can you make a suggestions?

John_w · Jan 21st 2020

You have to call Find_and_Activate_IE_Tab, which looks for the tab by its (partial) LocationURL or LocationName by looping through Shell.Windows. If found, it then calls UIAutomation_Click_IE_Tab to activate the tab. Find_and_Activate_IE_Tab uses the Like operator to look for the matching LocationURL or LocationName string, allowing wildcards in the TitleOrURL argument.

This works for me:

Code

 Public Sub Test()

    Dim IE As InternetExplorer
       
    Set IE = Find_and_Activate_IE_Tab("https://www.ozgrid.com/")
    If Not IE Is Nothing Then
        MsgBox "Found IE tab" & vbNewLine & _
               "LocationURL = " & IE.LocationURL & vbNewLine & _
               "LocationName = " & IE.LocationName
    Else
        MsgBox "Not found IE tab"
    End If
    
End Sub

Display More

cnan · Jan 25th 2020

John,

thank you for your reply.

What happens is:

If I put LocationURL instead of LocationName in Find_and_Activate_IE_Tab I get this error message:

at the line:

C

John_w · Jan 27th 2020

The error occurs at the yellow highlighted line because the IEtab object is Nothing. And IEtab is Nothing because there is no tab (a TabItemControl) with the name of your URL. The tab name of each tab in IE's UIAutomation elements is the LocationName, not the LocationURL.

Here is a detailed description of how the code works:

The main function, Find_and_Activate_IE_Tab, looks for the required tab by its LocationName or LocationURL. If found, it calls UIAutomation_Click_IE_Tab with the found LocationName and looks for the IE UI element with the specified tab name (a TabItemControl) and clicks (activates) that tab.

The 2nd argument to UIAutomation_Click_IE_Tab must be the LocationName of the tab to be activated, not the LocationURL. The reason is that, amongst all IE's UIAutomation elements, the UI element containing the LocationURL is that of the already active tab in IE's address bar - it is a UI element with the class name "AddressDisplay Control". Although the URL of a tab is displayed when you hover over that tab, I have not seen this URL anywhere in IE's UIAutomation elements, so I don't think the code could be changed to look for the URL.

cnan · Jan 28th 2020

Hi John,

thank you again for your effort to explain this for me.

Now I understand.

I am trying to select one tab from many where, unfortunatelly, the LocationName is the same. The tabs contain pages for different records of a database so only id differes in the LocationURL. This is all I got to work with.

So, I guess this is the end of my search for a solution to this.

BR!

John_w · Jan 28th 2020

Here is a new UIAutomation function, UIAutomation_Click_IE_Tab_By_URL, which activates the tab with the specified LocationURL. It finds the required tab by activating each tab in turn and extracting the URL from the IE address bar and comparing it to the required URL - which can contain wildcards, since the Like operator is used - until the required tab is activated.

Here is the complete code, including a test routine and a function which loops through all IE windows and tabs until the required LocationURL is found.

Code

'References required:
'Microsoft Internet Controls
'Microsoft Shell Controls and Automation
'UIAutomationClient

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As LongPtr)
#Else
    Private Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As Long)
#End If

Public Sub Test_IE_UIAutomation()

    Dim IE As InternetExplorer
       
    Set IE = Find_and_Activate_IE_Tab_By_URL("*ozgrid.com*")
    If Not IE Is Nothing Then
        Debug.Print "Activated IE tab"
        Debug.Print "LocationURL = "; IE.LocationURL
        Debug.Print "LocationName = "; IE.LocationName
    Else
        Debug.Print "Not activated IE tab"
    End If
    
End Sub


Private Function Find_and_Activate_IE_Tab_By_URL(findUrlLike As String) As InternetExplorer

    'Look for an IE browser window or tab which matches the specified URL (Like operator wildcards allowed).
    'If found, activate that IE tab and return it as an InternetExplorer object.  Otherwise return Nothing.
    'Works with multiple IE windows

    Dim Shell As Shell
    Dim IE As InternetExplorer
    Dim i As Variant        'must be a variant to access items in Shell.Windows() array
    Dim tabURL As String
    
    Set Shell = New Shell

    i = 0
    Set Find_and_Activate_IE_Tab_By_URL = Nothing
    While i < Shell.Windows.Count And Find_and_Activate_IE_Tab_By_URL Is Nothing
        Set IE = Shell.Windows(i)
        If Not IE Is Nothing Then
            If TypeName(IE.Document) = "HTMLDocument" Then
                If LCase(IE.LocationURL) Like LCase(findUrlLike) Then
                    'Found a tab or window which matches the specified URL, now activate it
                    tabURL = UIAutomation_Click_IE_Tab_By_URL(IE.hwnd, findUrlLike)
                    If tabURL <> "" Then Set Find_and_Activate_IE_Tab_By_URL = IE
                End If
            End If
        End If
        i = i + 1
    Wend
    
End Function


'Find and click (activate) a tab by its URL (can contain wildcards) and return its full URL from the IE address bar

#If VBA7 Then
Private Function UIAutomation_Click_IE_Tab_By_URL(IEhwnd As LongPtr, findUrlLike As String) As String
#Else
Private Function UIAutomation_Click_IE_Tab_By_URL(IEhwnd As Long, findUrlLike As String) As String
#End If
   
    Dim UIauto As IUIAutomation
    Dim IEwindow As IUIAutomationElement, IEtab As IUIAutomationElement
    Dim IEtabs As IUIAutomationElementArray
    Dim tabItemCondition As IUIAutomationCondition
    Dim addressBarCondition As IUIAutomationCondition
    Dim IEtabPattern As IUIAutomationLegacyIAccessiblePattern
    Dim IEaddressBar As IUIAutomationElement
    Dim i As Long
    Dim IEaddressBarUrl As String, prevIEaddressBarUrl As String
    
    'Create UIAutomation object
    
    Set UIauto = New CUIAutomation
            
    'Get Internet Explorer UIAutomation element
    
    Set IEwindow = UIauto.ElementFromHandle(ByVal IEhwnd)
    IEwindow.SetFocus   'optional - brings the IE window to the foreground
    
    'Create condition to find a TabItemControl
    
    Set tabItemCondition = UIauto.CreatePropertyCondition(UIA_ControlTypePropertyId, UIA_TabItemControlTypeId)
    
    'Find all tabs
    
    Set IEtabs = IEwindow.FindAll(TreeScope_Descendants, tabItemCondition)
    
    'Create condition to find the IE address bar. This is a control with class name "AddressDisplay Control"
        
    Set addressBarCondition = UIauto.CreatePropertyCondition(UIA_ClassNamePropertyId, "AddressDisplay Control")
    
    'Activate each tab until the one with the specified URL is found
    
    UIAutomation_Click_IE_Tab_By_URL = ""
    prevIEaddressBarUrl = ""
    i = 0
    While i < IEtabs.Length And UIAutomation_Click_IE_Tab_By_URL = ""
       
        'Find the IE address bar
        
        Set IEaddressBar = IEwindow.FindFirst(TreeScope_Descendants, addressBarCondition)

        'Get URL from address bar
        
        IEaddressBarUrl = IEaddressBar.GetCurrentPropertyValue(UIA_LegacyIAccessibleValuePropertyId)
        
        'Is this the required URL?
        
        If Not LCase(IEaddressBarUrl) Like LCase(findUrlLike) Then
        
            'No, so activate the next tab by invoking its DoDefaultAction method (Click)
            
            Set IEtab = IEtabs.GetElement(i)
            Set IEtabPattern = IEtab.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)
            IEtabPattern.DoDefaultAction
            DoEvents
            
            'Wait until the tab is activated, indicated by the URL being different to the previous URL
            
            Do
                Set IEaddressBar = IEwindow.FindFirst(TreeScope_Descendants, addressBarCondition)
                IEaddressBarUrl = IEaddressBar.GetCurrentPropertyValue(UIA_LegacyIAccessibleValuePropertyId)
                DoEvents
                Sleep 20
            Loop Until IEaddressBarUrl <> prevIEaddressBarUrl
            prevIEaddressBarUrl = IEaddressBarUrl
        
        Else
        
            'Yes, so return the full URL
            
            UIAutomation_Click_IE_Tab_By_URL = IEaddressBarUrl
       
        End If
        
        i = i + 1
    Wend
            
End Function

Display More

cnan · Jan 29th 2020

Hi John,

this is awesome!!!

Exactly what I needed

Thank you very much!

Is there another way (other then simply like your comments) to help your forum status (increase your points)?

Claudiu

John_w · Jan 29th 2020

Hi Claudiu,

Very pleased that the code works for you, and appreciate your kind comments.

Liking my posts is the only way other people can increase my points. The Points calculation doesn't make sense to me!

Built2Scale · Apr 22nd 2020

Hello,

This code works very well for locating and activating a tab based on URL. Is there a similar method to activate a tab based on the page title and make that IE window visible? I don't need it to match the URL, only the page title.

**royUK** · Apr 22nd 2020

Built2Scale

Welcome to Ozgrid. Please take a few minutes to read the Forum Rules then start your own question. You can add a link to this one if you think it helps.

Find correct tab in Internet Explorer and activate it

Participate now!

Share