Show filter value in a cell

Sub placefiltercritincomment()
Dim w As Worksheet
Dim f As Integer
Dim filterset As String
Dim currentFiltRange As String


Dim myrange As Range
Set w = ActiveSheet
With w.AutoFilter
    
    currentFiltRange = .Range.Address
    With .Filters
        
        For f = 1 To .Count
            filterset = ""
            With .Item(f)
                If .On Then
                    filterset = filterset & .Criteria1
                    If .Operator Then
                        filterset = filterset & .Operator
                        filterset = filterset & .Criteria2
                    End If
                End If
            End With
            Set myrange = w.AutoFilter.Range(f)
            On Error Resume Next
            myrange.Comment.Delete
            On Error GoTo 0
            If filterset <> "" Then
                myrange.AddComment filterset
            End If
        Next f
    End With
End With


End Sub

Function FilterCriteria(Rng As Range) As String
    'By Stephen Bullen
    Dim Filter As String
    Filter = ""
    On Error GoTo Finish
    With Rng.Parent.AutoFilter
        If Intersect(Rng, .Range) Is Nothing Then GoTo Finish
        With .Filters(Rng.Column - .Range.Column + 1)
            If Not .On Then GoTo Finish
            Filter = .Criteria1
            Select Case .Operator
                Case xlAnd
                    Filter = Filter & " AND " & .Criteria2
                Case xlOr
                    Filter = Filter & " OR " & .Criteria2
            End Select
        End With
    End With
Finish:
    FilterCriteria = Filter
End Function