Color Individual Lines Of Shape Group

StefanG · Feb 2nd 2008

Hello,

any idea how i could color fill a custom shape created by individual lines which are grouped together? The group behaves as one shape alright when, say, coloring the line, but is not "fillable". Below a simple sample. - The custom shape i am trying to color in is not a simple square or rectangle -not anything from the existing MS shapes that is.

Thank you,

Stefan

Code

Option Explicit
Sub Macro1()
    ActiveSheet.Shapes.AddLine(48#, 25.5, 144.75, 25.5).Select
        Selection.Name = "aLine"
    ActiveSheet.Shapes.AddLine(144.75, 25.5, 144.75, 102.75).Select
        Selection.Name = "bLine"
    ActiveSheet.Shapes.AddLine(48#, 102.75, 144.75, 102.75).Select
        Selection.ShapeRange.Flip msoFlipHorizontal
        Selection.Name = "cLine"
    ActiveSheet.Shapes.AddLine(48#, 25.5, 48#, 102.75).Select
        Selection.ShapeRange.Flip msoFlipVertical
        Selection.Name = "dLine"
    ActiveSheet.Shapes.Range(Array("aLine", "bLine", "cLine", "dLine")).Select
        Selection.ShapeRange.Group.Select
        Selection.Name = "AllLines"
End Sub

Display More

shg · Feb 2nd 2008

Re: Color Fill Custom Shape Group

Use a polyline.

Code

Sub Macro1()
    Dim afSAoP() As Single ' SafeArrayOfPoints
    Dim shp As Shape
    
    ReDim afSAoP(1 To 11, 1 To 2)
    
    afSAoP(1, 1) = 100: afSAoP(1, 2) = 0
    afSAoP(2, 1) = 122: afSAoP(2, 2) = 69
    afSAoP(3, 1) = 195: afSAoP(3, 2) = 69
    afSAoP(4, 1) = 136: afSAoP(4, 2) = 112
    afSAoP(5, 1) = 159: afSAoP(5, 2) = 181
    afSAoP(6, 1) = 100: afSAoP(6, 2) = 138
    afSAoP(7, 1) = 41: afSAoP(7, 2) = 181
    afSAoP(8, 1) = 64: afSAoP(8, 2) = 112
    afSAoP(9, 1) = 5: afSAoP(9, 2) = 69
    afSAoP(10, 1) = 78: afSAoP(10, 2) = 69
    afSAoP(11, 1) = 100: afSAoP(11, 2) = 0
    
    Set shp = ActiveSheet.Shapes.AddPolyline(afSAoP)
    With shp
        .Placement = xlFreeFloating
        .Line.Visible = msoTrue
        .Line.DashStyle = msoLineSolid
        .Line.ForeColor.RGB = RGB(255, 0, 0)
        .Line.Weight = 3
        .Fill.Visible = msoTrue
        .Fill.ForeColor.RGB = RGB(0, 0, 255)
        .Fill.Solid
        .Fill.Transparency = 0
        .Shadow.Visible = msoFalse
        .ZOrder msoSendToBack
    End With
    
End Sub

Display More

StefanG · Feb 4th 2008

Re: Color Individual Lines Of Shape Group

Hello,
this looks great!
I am having difficulties understanding how this works. For practice i tried to create the same shape, same location, as in my sample, needless to say without luck. Excel's help is, well, not much help.
May i ask if you are willing to help me further please? How would i use the approach you suggested, which i like alot, to create a shape using the data as shown in the sample in my original post, in the same location / coordinates of the sample?
Thank you very much.
Stefan

p.s.
since i have existing shapes, based on lines like in the sample. how do i translate that best?

**Andy Pope** · Feb 4th 2008

Re: Color Individual Lines Of Shape Group

Slight variation on Shg's as I used a freeform shape.
The macro recorder provider the code.

[vba]
With ActiveSheet.Shapes.BuildFreeform(msoEditingAuto, 48, 25.5)
.AddNodes msoSegmentLine, msoEditingAuto, 144.75, 25.5
.AddNodes msoSegmentLine, msoEditingAuto, 144.75, 102.75
.AddNodes msoSegmentLine, msoEditingAuto, 48.75, 102.75
.AddNodes msoSegmentLine, msoEditingAuto, 48, 25.5
.ConvertToShape.Select
End With
[/vba]

Aaron Blood · Feb 4th 2008

Re: Color Individual Lines Of Shape Group

Just out of curiosity...

What sort of application are you developing that requires drawing polygons with Excel?

shg · Feb 4th 2008

Re: Color Individual Lines Of Shape Group

Quote

I am having difficulties understanding how this works.

Stefan,

The SAoP is just a list of points where (i, 1) is the x coordinate and (i, 2) is the y coordinate. Make the last point the same as the first to close the plot: SAoP(n, 1) = SAoP(1, 1) and SAoP(n, 2) = SAoP(1, 2).

Aaron,

Here's an example of where I've used it. It's a field of view plot (compressed down to 50KB) of the cockpit windows of a Beech 400A from the pilot's eyepoint. Points (butt line, station, and waterline) on the window outlines were taken from a CAD drawing, re-referenced to the pilot's eyepoint, and projected to a Hammer plot.

StefanG · Feb 4th 2008

Re: Color Individual Lines Of Shape Group

Andy, shg, Aaron,
thank you very much for all your help. This is great. Now i have a couple different ways to go about. - My goal is not as complex as what shg has shown on the "world" sample. I am just trying to build a shape similar to Draw > AutoShapes > Basic Shapes > Bevel, that allows me to color the border parts, which cannot be done individually in the said shape set up. - Now i am off to applying what i learned here.Thank you again.
Stefan

Color Individual Lines Of Shape Group

Participate now!

Share